path: root/app-admin/kern/kern-0.6.0-r1.ebuild

# Copyright 2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

VERIFY_SIG_METHOD="signify"
inherit verify-sig

DESCRIPTION="Configure, build, and install kernels on Gentoo Linux"
HOMEPAGE="https://git.oriole.systems/kern"
SRC_URI="
	https://git.oriole.systems/${PN}/snapshot/${P}.tar.gz
	verify-sig? (
		https://git.oriole.systems/${PN}/snapshot/${P}.tar.gz.asc
			-> ${P}.sha.sig
	)
"

RESTRICT="mirror"

LICENSE="ISC"
SLOT="0"
KEYWORDS="amd64 x86"

RDEPEND="${DEPEND}
	app-admin/eclean-kernel"

VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/signify-keys/oriole-systems-20240330.pub"

src_unpack() {
	if use verify-sig; then
		cp "${DISTDIR}"/${P}.{sha.sig,tar.gz} "${WORKDIR}" || die
		verify-sig_verify_signed_checksums \
			${P}.sha.sig sha256 ${P}.tar.gz
	fi
	default
}

src_compile() { :; }

src_install() {
	emake PREFIX=/usr DESTDIR="${D}" install

	insinto /usr/share/fish/vendor_completions.d
	doins contrib/completion/kern.fish
}