path: root/app-portage/bosun/bosun-1.4.0-r2.ebuild

# Copyright 2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

VERIFY_SIG_METHOD="signify"
inherit verify-sig

DESCRIPTION="Manage portage roles with stow(8)"
HOMEPAGE="https://git.oriole.systems/bosun"
SRC_URI="
	https://git.oriole.systems/${PN}/snapshot/${P}.tar.gz
	verify-sig? (
		https://git.oriole.systems/${PN}/snapshot/${P}.tar.gz.asc
			-> ${P}.sha.sig
	)
"

LICENSE="ISC"
SLOT="0"
KEYWORDS="amd64 x86"
RESTRICT="mirror"

DEPEND="app-admin/stow"
RDEPEND="${DEPEND}"
BDEPEND="verify-sig? ( sec-keys/signify-keys-oriole-systems )"

VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/signify-keys/oriole-systems-20240330.pub"

src_unpack() {
	if use verify-sig; then
		cp "${DISTDIR}"/${P}.{sha.sig,tar.gz} "${WORKDIR}" || die
		verify-sig_verify_signed_checksums \
			${P}.sha.sig sha256 ${P}.tar.gz
	fi
	default
}

src_compile() { :; }

src_install() {
	emake PREFIX=/usr DESTDIR="${D}" install

	insinto /usr/share/fish/vendor_completions.d
	doins contrib/completion/bosun.fish
}