1 files changed, 43 insertions, 0 deletions
diff --git a/x11-wm/cwm/cwm-7.0.ebuild b/x11-wm/cwm/cwm-7.0.ebuild
new file mode 100644
index 0000000..c184da6
--- /dev/null
+++ b/x11-wm/cwm/cwm-7.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop toolchain-funcs
+
+DESCRIPTION="A Linux port and fork of OpenBSD's cwm(1)"
+HOMEPAGE="https://git.oriole.systems/cwm/about/
+	https://www.openbsd.org/cgi-bin/cvsweb/xenocara/app/cwm/
+"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.oriole.systems/cwm"
+else
+	SRC_URI="https://git.oriole.systems/cwm/snapshot/${P}.tar.gz"
+	KEYWORDS="amd64 arm arm64 x86"
+fi
+
+RESTRICT="mirror"
+
+LICENSE="ISC"
+SLOT="0"
+
+DEPEND="x11-libs/libXft
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	sys-devel/bison
+	virtual/pkgconfig
+"
+
+src_compile() {
+	emake CFLAGS="${CFLAGS} -D_GNU_SOURCE" CC="$(tc-getCC)" PKG_CONFIG="$(tc-getPKG_CONFIG)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX=/usr install
+	make_session_desktop ${PN} ${PN}
+}