1 files changed, 45 insertions, 0 deletions
diff --git a/app-office/fava/fava-1.23.1.ebuild b/app-office/fava/fava-1.23.1.ebuild
new file mode 100644
index 0000000..dbe50e1
--- /dev/null
+++ b/app-office/fava/fava-1.23.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9,10} )
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1
+
+DESCRIPTION="Web interface for the accounting tool Beancount"
+HOMEPAGE="https://beancount.github.io/fava/ https://pypi.org/project/fava/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=app-office/beancount-2.3.0[${PYTHON_SINGLE_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/Babel-2.7.0[${PYTHON_USEDEP}]
+		>=dev-python/cheroot-8.5.2[${PYTHON_USEDEP}]
+		>=dev-python/flask-babel-1.0.0[${PYTHON_USEDEP}]
+		>=dev-python/flask-2.0.1[${PYTHON_USEDEP}]
+		>=dev-python/jinja-3.0.1[${PYTHON_USEDEP}]
+		>=dev-python/click-8.0.1[${PYTHON_USEDEP}]
+		>=dev-python/markdown2-2.3.0[${PYTHON_USEDEP}]
+		dev-python/ply[${PYTHON_USEDEP}]
+		>=dev-python/simplejson-3.16.0[${PYTHON_USEDEP}]
+		>=dev-python/werkzeug-1.0.0[${PYTHON_USEDEP}]
+		dev-python/chardet[${PYTHON_USEDEP}]
+		')
+	"
+
+python_test() {
+	# test_static_url presumes and requires the existence of these two files.
+	# They need only to exist in order for the code to determine the mtime
+	# value.
+	mkdir -p fava/static/{javascript,css} || die
+	touch fava/static/javascript/main.ts || die
+	touch fava/static/css/style.css || die
+
+	py.test -v || die
+}