www-apps/cgit: Add 1.2.3.-r1

This ebuild differs greatly from the official one in the main tree and
should be considered experimental.

We fully remove webapp-config support, since our setup is not compatible
at all with Gentoo assumptions. Furthermore, we have added missing USE
flags and converted the ebuild to EAPI 7.

Package-Manager: Portage-2.3.99, Repoman-2.3.22

1 files changed, 83 insertions, 0 deletions

diff --git a/www-apps/cgit/cgit-1.2.3-r1.ebuild b/www-apps/cgit/cgit-1.2.3-r1.ebuild
new file mode 100644
index 0000000..10d8602
--- /dev/null
+++ b/www-apps/cgit/cgit-1.2.3-r1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib toolchain-funcs
+
+GIT_V="2.25.1"
+
+DESCRIPTION="a fast web-interface for git repositories"
+HOMEPAGE="https://git.zx2c4.com/cgit/about"
+SRC_URI="https://www.kernel.org/pub/software/scm/git/git-${GIT_V}.tar.xz
+	https://git.zx2c4.com/cgit/snapshot/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc highlight libressl lua luajit lzip markdown zip zstd"
+
+LUADEP="
+	lua? (
+		luajit? ( dev-lang/luajit )
+		!luajit? ( dev-lang/lua:0 )
+	)
+"
+
+BDEPEND="
+	doc? ( app-text/docbook-xsl-stylesheets
+		>=app-text/asciidoc-8.5.1 )
+"
+
+RDEPEND="${LUADEP}
+	dev-vcs/git
+	highlight? ( || ( dev-python/pygments app-text/highlight ) )
+	lzip? ( app-arch/lzip )
+	markdown? ( dev-python/markdown )
+	zip? ( app-arch/zip )
+	zstd? ( app-arch/zstd )
+"
+
+DEPEND="${LUADEP}
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	sys-libs/zlib
+"
+
+src_prepare() {
+	default
+
+	rmdir git || die
+	mv "${WORKDIR}"/git-"${GIT_V}" git || die
+
+	echo "prefix = ${EPREFIX}/usr" >> cgit.conf
+	echo "libdir = ${EPREFIX}/usr/$(get_libdir)" >> cgit.conf
+	echo "CACHE_ROOT = ${CGIT_CACHEDIR}" >> cgit.conf
+	echo "DESTDIR = ${D}" >> cgit.conf
+	if use lua; then
+		if use luajit; then
+			echo "LUA_PKGCONFIG = luajit" >> cgit.conf
+		else
+			echo "LUA_PKGCONFIG = lua" >> cgit.conf
+		fi
+	else
+		echo "NO_LUA = 1" >> cgit.conf
+	fi
+}
+
+src_compile() {
+	emake V=1 AR="$(tc-getAR)" CC="$(tc-getCC)" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
+	use doc && emake V=1 doc-man
+}
+
+src_install() {
+	emake V=1 AR="$(tc-getAR)" CC="$(tc-getCC)" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" install
+
+	dodoc README
+	use doc && doman cgitrc.5
+}
+
+pkg_postinst() {
+	ewarn "For caching support, /var/cache/cgit needs to exist and be owned"
+	ewarn "by the user executing cgit."
+}