From 81776ff455a5c30f9d40c6b62c1eba096120e327 Mon Sep 17 00:00:00 2001
From: Wolfgang Müller
Date: Thu, 30 Sep 2021 11:17:54 +0200
Subject: net-analyzer/goaccess: Bump to 1.5.2

Package-Manager: Portage-3.0.20, Repoman-3.0.3
---
 net-analyzer/goaccess/goaccess-1.5.2.ebuild | 51 +++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 net-analyzer/goaccess/goaccess-1.5.2.ebuild

(limited to 'net-analyzer/goaccess/goaccess-1.5.2.ebuild')

diff --git a/net-analyzer/goaccess/goaccess-1.5.2.ebuild b/net-analyzer/goaccess/goaccess-1.5.2.ebuild
new file mode 100644
index 0000000..78f9457
--- /dev/null
+++ b/net-analyzer/goaccess/goaccess-1.5.2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+if [[ ${PV} = *9999* ]] ; then
+	EGIT_REPO_URI="https://github.com/allinurl/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://tar.goaccess.io/${P}.tar.gz"
+	KEYWORDS="amd64 x86 amd64-linux"
+fi
+
+DESCRIPTION="A real-time web log analyzer and interactive viewer that runs in a terminal"
+HOMEPAGE="https://goaccess.io"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="debug geoip geoipv2 getline ssl unicode"
+REQUIRED_USE="geoipv2? ( geoip )"
+
+BDEPEND="virtual/pkgconfig"
+RDEPEND="sys-libs/ncurses:=[unicode(+)?]
+	geoip? (
+		!geoipv2? ( dev-libs/geoip )
+		geoipv2? ( dev-libs/libmaxminddb:0= )
+	)
+	ssl? (
+		dev-libs/openssl:0=
+	)"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# Change path to GeoIP bases in config
+	sed -i -e s':/usr/local:/usr:' config/goaccess.conf || die "sed failed for goaccess.conf"
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		"$(use_enable debug)" \
+		"$(use_enable geoip geoip "$(usex geoipv2 mmdb legacy)")" \
+		"$(use_enable unicode utf8)" \
+		"$(use_with getline)" \
+		"$(use_with ssl openssl)"
+}
-- 
cgit v1.2.3-2-gb3c3