From e2ff253f7e4491ccf76b9e10e13f91fd3607db3c Mon Sep 17 00:00:00 2001
From: Wynn Wolf Arbor
Date: Sun, 19 Apr 2020 18:54:47 +0200
Subject: dev-python/flask-babel: Bump to 1.0.0-r1

This will stabilize flask-babel-1.0.0 and drop support for python 3.6.

Package-Manager: Portage-2.3.89, Repoman-2.3.20
---
 dev-python/flask-babel/flask-babel-1.0.0-r1.ebuild | 56 ++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 dev-python/flask-babel/flask-babel-1.0.0-r1.ebuild

(limited to 'dev-python/flask-babel/flask-babel-1.0.0-r1.ebuild')

diff --git a/dev-python/flask-babel/flask-babel-1.0.0-r1.ebuild b/dev-python/flask-babel/flask-babel-1.0.0-r1.ebuild
new file mode 100644
index 0000000..92f05d4
--- /dev/null
+++ b/dev-python/flask-babel/flask-babel-1.0.0-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python2_7 python3_{7,8} )
+inherit distutils-r1
+
+MY_PN="Flask-Babel"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="i18n and l10n support for Flask based on Babel and pytz"
+HOMEPAGE="https://pythonhosted.org/Flask-Babel/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/Babel[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/flask-sphinx-themes[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	sed -i -e "s/, 'sphinx.ext.intersphinx'//" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	nosetests -v || die "Tests failed under ${EPYTHON}"
+}
-- 
cgit v1.2.3-2-gb3c3