From 766a7e83c141528b58ed46670c7344c58f6b2ff8 Mon Sep 17 00:00:00 2001
From: Wolfgang Müller
Date: Mon, 12 Feb 2024 11:24:51 +0100
Subject: app-office/fava: add 1.27.2, drop 1.27.1

---
 app-office/fava/fava-1.27.2.ebuild | 50 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 app-office/fava/fava-1.27.2.ebuild

(limited to 'app-office/fava/fava-1.27.2.ebuild')

diff --git a/app-office/fava/fava-1.27.2.ebuild b/app-office/fava/fava-1.27.2.ebuild
new file mode 100644
index 0000000..9affd4b
--- /dev/null
+++ b/app-office/fava/fava-1.27.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10,11} )
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Web interface for the accounting tool Beancount"
+HOMEPAGE="https://beancount.github.io/fava/ https://pypi.org/project/fava/"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=app-office/beancount-2.3.5[${PYTHON_SINGLE_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/Babel-2.7.0[${PYTHON_USEDEP}]
+		>=dev-python/cheroot-8.5.2[${PYTHON_USEDEP}]
+		>=dev-python/flask-babel-1.0.0[${PYTHON_USEDEP}]
+		>=dev-python/flask-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/jinja-3.0.1[${PYTHON_USEDEP}]
+		>=dev-python/click-8.0.1[${PYTHON_USEDEP}]
+		>=dev-python/markdown2-2.3.0[${PYTHON_USEDEP}]
+		dev-python/ply[${PYTHON_USEDEP}]
+		>=dev-python/simplejson-3.16.0[${PYTHON_USEDEP}]
+		>=dev-python/werkzeug-2.3.0[${PYTHON_USEDEP}]
+		dev-python/chardet[${PYTHON_USEDEP}]
+		')
+	"
+
+python_prepare_all() {
+	sed -i -e 's:build-backend = "_build_backend":build-backend = "setuptools.build_meta":' pyproject.toml || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# test_static_url presumes and requires the existence of these two files.
+	# They need only to exist in order for the code to determine the mtime
+	# value.
+	mkdir -p fava/static/{javascript,css} || die
+	touch fava/static/javascript/main.ts || die
+	touch fava/static/css/style.css || die
+
+	py.test -v || die
+}
-- 
cgit v1.2.3-2-gb3c3