From e46f2078c77bace61f68dea97119026157d954ad Mon Sep 17 00:00:00 2001
From: Wynn Wolf Arbor
Date: Wed, 19 Feb 2020 20:10:44 +0100
Subject: dev-python/flask-babel: Add 1.0.0

Package-Manager: Portage-2.3.84, Repoman-2.3.20
---
 dev-python/flask-babel/Manifest                 |  3 ++
 dev-python/flask-babel/flask-babel-1.0.0.ebuild | 56 +++++++++++++++++++++++++
 dev-python/flask-babel/metadata.xml             | 13 ++++++
 3 files changed, 72 insertions(+)
 create mode 100644 dev-python/flask-babel/Manifest
 create mode 100644 dev-python/flask-babel/flask-babel-1.0.0.ebuild
 create mode 100644 dev-python/flask-babel/metadata.xml

diff --git a/dev-python/flask-babel/Manifest b/dev-python/flask-babel/Manifest
new file mode 100644
index 0000000..2cb6db5
--- /dev/null
+++ b/dev-python/flask-babel/Manifest
@@ -0,0 +1,3 @@
+DIST Flask-Babel-1.0.0.tar.gz 49680 BLAKE2B 29adeb7b4a6892fabf6e85da9f2fdb72f3871e3c3728c7521e06ffd80d8da505045eb1ef7a30223d8ef40064bc78514f6fc9acd1b8640232adb203ea55876e93 SHA512 3624b2e4877821551267e2719d76b714bda0a1da24e5a3c36d045273039823c4f3bbdf28cad5d8e0d4f0c896578248bfc40aebee720b543e500edf6de607ad8d
+EBUILD flask-babel-1.0.0.ebuild 1232 BLAKE2B ac76207843801d484416f47ba40ff187f6eef640fc3a02f7e6746ba7cf002be6643585d89fd349caff550335085679bd98240472445d6ea798cc12e515c295f4 SHA512 80945629b8f2d6f4bde7073ad754e66b617ce24a1ed55652ff39cf62d4b74eaefa58e883b0135c79d96e641774ce9f75d3868bbe762339272d8d6ca1705f7840
+MISC metadata.xml 450 BLAKE2B db38ca56f4b683429248baf7411355305672c23126c4b6c7486971fb1e099bb3117b9246870a24f6ecd66e7f27647e80285461d046c02e9227970a111c58dd98 SHA512 d6fb2f7cdf0a8d4b54dce372bbb3d9728a5ebb0e6d714da9c58e5215d6711e3f4211e2a6ef5390cdfa663d375d7e2942a210bfa2822489dd04a911d9e9c24985
diff --git a/dev-python/flask-babel/flask-babel-1.0.0.ebuild b/dev-python/flask-babel/flask-babel-1.0.0.ebuild
new file mode 100644
index 0000000..775d2c7
--- /dev/null
+++ b/dev-python/flask-babel/flask-babel-1.0.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python2_7 python3_{6,7,8} )
+inherit distutils-r1
+
+MY_PN="Flask-Babel"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="i18n and l10n support for Flask based on Babel and pytz"
+HOMEPAGE="https://pythonhosted.org/Flask-Babel/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/Babel[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/flask-sphinx-themes[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	sed -i -e "s/, 'sphinx.ext.intersphinx'//" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	nosetests -v || die "Tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/flask-babel/metadata.xml b/dev-python/flask-babel/metadata.xml
new file mode 100644
index 0000000..ee71c5b
--- /dev/null
+++ b/dev-python/flask-babel/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">Flask-Babel</remote-id>
+		<remote-id type="github">python-babel/flask-babel</remote-id>
+		<bugs-to>https://github.com/python-babel/flask-babel/issues</bugs-to>
+	</upstream>
+</pkgmetadata>
-- 
cgit v1.2.3-2-gb3c3